/* Bohren zu PROBOARD */

local "Mode";
/* Der gewünschte Modus kann hier eingestellt werden:
   1 = manueller Werkz.wechsel
   2 = automatischer Werkz.wechsel
*/
Mode = 1;

if(Mode == 1)
{
/* Bohren mit manuellem Werkzeugwechsel --------------- */

if(_mode == 'G')	/* was im Grafik-Modus zu tun ist */
{
 (MacroDef "t") = "r = %2;";	/* Radius merken */
 (MacroDef "d") = "MCirc %1 %2 r;"; /* Kreis anzeigen */
}

if(_mode != 'G'){
 (MacroDef "t") = "
  z zup + 20; mf;	/* um so viel weiter hochfahren */
  _oStatPrv = _oStat; _PrgOff; /* Spindel usw. aus */
  wait 0;
  r = %2;
  msg = sprint \"Bitte Werkzeug %d mit Durchmesser %6.2lf einspannen!\" (%1 + 0L) (2.0 * r);
  msgbox msg \"Manueller Wekzeugwechsel\" MB_OK or MB_ICONEXCLAMATION;
  _PrgOn;
 ";

 (MacroDef "d") = "
  z zup; mf;
  x %1; y %2; mf;
  z zdn1; ml;
  z zdn2; mld;
  z zup; mf;
 ";
}

}

if(Mode == 2)
{
/* Bohren mit automatischem Werkzeugwechsel --------------- */
/* Achtung: Das Werkzeug wird nur nach der T-Nummer ausgewählt.
   Die Soll-Zuordnung zu den Durchmessern ist in Datei Proboard.ddm.
   Abweichungen von den Istwerten der aktuellen Werkzeuge werden nicht geprüft!
*/
if(_mode == 'G')	/* was im Grafik-Modus zu tun ist */
{
 (MacroDef "t") = "r = (ToolPar \"rad\")[%1];";	/* Radius aus der Werkzeugtabelle holen */
 (MacroDef "d") = "MCirc %1 %2 r;"; /* Kreis anzeigen */
}

if(_mode != 'G'){
 (MacroDef "t") = "_ToolSel = %1; fcall _Path & \"/GetTool.ts\";
  r = (ToolPar \"rad\")[%1];
 ";

 (MacroDef "d") = "
  z zup; mf;
  x %1; y %2; mf;
  z zdn1; ml;
  z zdn2; mld;
  z zup; mf;
 ";
}

}